如何使用 XSLT 向 XML 的根元素添加命名空间？
声明：本页面是StackOverFlow热门问题的中英对照翻译，遵循CC BY-SA 4.0协议，如果您需要使用它，必须同样遵循CC BY-SA许可，注明原文地址和作者信息，同时你必须将它归于原作者（不是我）：StackOverFlow
原文地址: http://stackoverflow.com/questions/15981488/
Warning: these are provided under cc-by-sa 4.0 license. You are free to use/share it, But you must attribute it to the original authors (not me):
StackOverFlow
How can I add namespaces to the root element of my XML using XSLT?
提问by Ironman
I have an input XML
我有一个输入 XML
<Request>
<Info>
<Country>US</Country>
<Part>A</Part>
</Info>
</Request>
My output should be like
我的输出应该像
<Request
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:xsd="http://www.w3.org/2001/XMLSchema"
xmlns="http://hgkl.kj.com">
<Info>
<Country>US</Country>
<Part>A</Part>
</Info>
</Request>
Please let me know how to add the multiple namespaces and a default namespace like the above XML.
请让我知道如何添加多个命名空间和一个默认命名空间，如上述 XML。
回答by Daniel Haley
Here's how I'd do it in XSLT 2.0...
这是我在 XSLT 2.0 中的做法...
XML Input
XML 输入
<Request>
<Info>
<Country>US</Country>
<Part>A</Part>
</Info>
</Request>
XSLT 2.0
XSLT 2.0
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="*" priority="1">
<xsl:element name="{local-name()}" namespace="http://hgkl.kj.com">
<xsl:namespace name="xsi" select="'http://www.w3.org/2001/XMLSchema-instance'"/>
<xsl:namespace name="xsd" select="'http://www.w3.org/2001/XMLSchema'"/>
<xsl:apply-templates select="@*|node()"/>
</xsl:element>
</xsl:template>
</xsl:stylesheet>
XML Output
XML 输出
<Request xmlns="http://hgkl.kj.com"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:xsd="http://www.w3.org/2001/XMLSchema">
<Info>
<Country>US</Country>
<Part>A</Part>
</Info>
</Request>
Here's an XSLT 1.0option which produces the same output, but requires you to know the name of the root element...
这是一个XSLT 1.0选项，它产生相同的输出，但要求您知道根元素的名称...
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="@*|text()|comment()|processing-instruction()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="/Request">
<Request xmlns="http://hgkl.kj.com"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:xsd="http://www.w3.org/2001/XMLSchema">
<xsl:apply-templates select="@*|node()"/>
</Request>
</xsl:template>
<xsl:template match="*">
<xsl:element name="{local-name()}" namespace="http://hgkl.kj.com">
<xsl:apply-templates select="@*|node()"/>
</xsl:element>
</xsl:template>
</xsl:stylesheet>
