使用 VBA 从 Outlook 2010 保存 .XLSX 附件

Saving .XLSX Attachments from Outlook 2010 w/ VBA

提问by CSharp821

We use Outlook 2010 and receive emails with Excel attachments. We manually save the attachment in a sub-folder that we create within a divisional folder on a network drive.

我们使用 Outlook 2010 并接收带有 Excel 附件的电子邮件。我们手动将附件保存在我们在网络驱动器上的分区文件夹中创建的子文件夹中。

What I'm curious about is if it's possible to

我很好奇的是是否有可能

1. Use code to check incoming emails to see if they have an attachment,
2. Then check the attachment to see if it's an .XLSX,
3. If so, open the attachment, check the value of a particular cell,
4. then store the account name and account number as a string and a variable
5. then use those to create the sub-folders in the appropriate Windows directory.

1. 使用代码检查收到的电子邮件，看看它们是否有附件，
2. 然后检查附件是否是 .XLSX，
3. 如果是这样，打开附件，检查特定单元格的值，
4. 然后将帐户名称和帐户编号存储为字符串和变量
5. 然后使用它们在适当的 Windows 目录中创建子文件夹。

** I forgot to post what I had done so far. I believe Brett answered my ??, but maybe someone else would be able to use snippets of it.

** 我忘了发布我到目前为止所做的事情。我相信布雷特回答了我的 ??，但也许其他人可以使用它的片段。

Private Sub cmdConnectToOutlook_Click()
Dim appOutlook As Outlook.Application
Dim ns As Outlook.Namespace
Dim inbox As Outlook.MAPIFolder
Dim item As Object
Dim atmt As Outlook.Attachment
Dim filename As String
Dim i As Integer

Set appOutlook = GetObject(, "Outlook.Application")
Set ns = appOutlook.GetNamespace("MAPI")
Set inbox = ns.GetDefaultFolder(olFolderInbox)
i = 0 

If inbox.Items.Count = 0 Then
    MsgBox "There are no messages in the Inbox.", vbInformation, _
           "Nothing Found"
    Exit Sub
End If

For Each item In inbox.Items
  For Each atmt In item.Attachments

    If Right(atmt.filename, 4) = "xlsx" Then
        filename = "\temp\" & atmt.filename
        atmt.SaveAsFile filename
       i = i + 1
    End If

  Next atmt
Next item

MsgBox "Attachments have been saved.", vbInformation, "Finished"

Set atmt = Nothing
Set item = Nothing
Set ns = Nothing

End Sub

结束子

回答by brettdj

Having said it is lengthy here is one way to do it. My code from VBA Code to save an attachment (excel file) from an Outlook email that was inside another email as an attachmentmay also be of interest

话虽如此，这里很长，这是一种方法。我来自VBA 代码的代码用于将另一封电子邮件中的 Outlook 电子邮件中的附件（excel 文件）保存为附件也可能很有趣

You will need to update your file path, and the cell range from the file that you are opening

您将需要更新您的文件路径，以及您正在打开的文件的单元格范围

In my testing I sent a message to myself with a pdf file and an excel workbook with "bob" in the A1 in the first sheet

在我的测试中，我向自己发送了一条消息，其中包含一个 pdf 文件和一个在第一张纸的 A1 中带有“bob”的 Excel 工作簿

The code below found the excel file, saved it, opened it, create a directory c:\temp\bobthen killed the saved file

下面的代码找到excel文件，保存它，打开它，创建一个目录c:\temp\bob然后杀死保存的文件

Private Sub Application_NewMailEx _
    (ByVal EntryIDCollection As String)

'Uses the new mail techniquer from http://www.outlookcode.com/article.aspx?id=62

Dim arr() As String
Dim lngCnt As Long
Dim olAtt As Attachment
Dim strFolder As String
Dim strFileName As String
Dim strNewFolder
Dim olns As Outlook.NameSpace
Dim olItem As MailItem
Dim objExcel As Object
Dim objWB As Object

'Open Excel in the background
Set objExcel = CreateObject("excel.application")

'Set working folder
strFolder = "c:\temp"

On Error Resume Next
Set olns = Application.Session
arr = Split(EntryIDCollection, ",")
On Error GoTo 0

For lngCnt = 0 To UBound(arr)
    Set olItem = olns.GetItemFromID(arr(lngCnt))
    'Check new item is a mail message
    If olItem.Class = olMail Then
        'Force code to count attachments
        DoEvents
        For Each olAtt In olItem.Attachments
            'Check attachments have at least 5 characters before matching a ".xlsx" string
            If Len(olAtt.FileName) >= 5 Then
                If Right$(olAtt.FileName, 5) = ".xlsx" Then
                    strFileName = strFolder & "\" & olAtt.FileName
                    'Save xl attachemnt to working folder
                    olAtt.SaveAsFile strFileName
                    On Error Resume Next
                    'Open excel workbook and make a sub directory in the working folder with the value from A1 of the first sheet
                    Set objWB = objExcel.Workbooks.Open(strFileName)
                    MkDir strFolder & "\" & objWB.sheets(1).Range("A1")
                    'Close the xl file
                    objWB.Close False
                    'Delete the saved attachment
                    Kill strFileName
                    On Error Goto 0
                End If
            End If
        Next
    End If
Next
'tidy up
Set olns = Nothing
Set olItem = Nothing
objExcel.Quit
Set objExcel = Nothing
End Sub