vba VBScript 打开一个对话框来选择文件路径

VBScript to open a dialog to select a filepath

提问by StuartM

At present I am opening a file with my vbscript as follows:

目前我正在用我的 vbscript 打开一个文件，如下所示：

strFile = "C:\Users\test\file.txt"
Set objFile = objFSO.OpenTextFile(strFile)

I would like to change this so that a file can be selected/navigated to by the user and that file is used in the script. How can I add this ability? I have tried to search for how to load a file dialog/prompt the user for a file etc just not sure how to complete in a VBScript.

我想改变这一点，以便用户可以选择/导航到一个文件，并在脚本中使用该文件。我怎样才能添加这个能力？我试图搜索如何加载文件对话框/提示用户输入文件等，只是不确定如何在 VBScript 中完成。

回答by PatricK

There is another solution I found interesting from MS TechNetless customization but gets what you wanted to achieve. This returns the full path of the selected file.

我从MS TechNet 中发现了另一种有趣的解决方案，较少定制，但可以实现您想要实现的目标。这将返回所选文件的完整路径。

Set wShell=CreateObject("WScript.Shell")
Set oExec=wShell.Exec("mshta.exe ""about:<input type=file id=FILE><script>FILE.click();new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).WriteLine(FILE.value);close();resizeTo(0,0);</script>""")
sFileSelected = oExec.StdOut.ReadLine
wscript.echo sFileSelected

回答by Nathan Rice

Here you go:

干得好：

http://www.robvanderwoude.com/vbstech_ui_fileopen.php

http://www.robvanderwoude.com/vbstech_ui_fileopen.php

strFile = GetFileName("C:\Users\test\", "Text files|*.txt")
Set objFile = objFSO.OpenTextFile(strFile)

Function GetFileName( myDir, myFilter )
  ' Written by Rob van der Woude
  ' http://www.robvanderwoude.com

  ' Standard housekeeping
  Dim objDialog

  ' Create a dialog object
  Set objDialog = CreateObject( "UserAccounts.CommonDialog" )

  ' Check arguments and use defaults when necessary
  If myDir = "" Then
    ' Default initial folder is "My Documents"
    objDialog.InitialDir = CreateObject( "WScript.Shell" ).SpecialFolders( "MyDocuments" )
  Else
    ' Use the specified initial folder
    objDialog.InitialDir = myDir
  End If
  If myFilter = "" Then
    ' Default file filter is "All files"
    objDialog.Filter = "All files|*.*"
  Else
    ' Use the specified file filter
    objDialog.Filter = myFilter
  End If

  ' Open the dialog and return the selected file name
  If objDialog.ShowOpen Then
    GetFileName = objDialog.FileName
  Else
    GetFileName = ""
  End If
End Function

回答by Hermolaou

VBSEdit program installs a COM library VBSEdit Toolkit, which allows Open File dialogs.

VBSEdit 程序安装了一个 COM 库 VBSEdit Toolkit，它允许打开文件对话框。

From VBSEdit help:

从 VBSEdit 帮助：

Dialog boxes 
OpenFileDialog method
Prompt the user to open a file
toolkit.OpenFileDialog ([initialFolder,[filters,[multiselect,[title]]]]) 

'Opens a single file
Set toolkit = CreateObject("VbsEdit.Toolkit")
files=toolkit.OpenFileDialog("c:\scripts\","Text Files (*.txt)|*.txt",False,"Open a text file")
If UBound(files)>=0 Then
  WScript.Echo files(0)
Else
  Wscript.Quit
End If

'Opens multiple files
Set toolkit = CreateObject("VbsEdit.Toolkit")
files=toolkit.OpenFileDialog("c:\scripts\","Text Files (*.txt)|*.txt",True,"Open a text file")
If UBound(files)>=0 Then
  For Each filepath In files
    WScript.Echo filepath
  Next
Else
  Wscript.Quit
End If



SaveFileDialog method
Prompt the user to save a file
toolkit.SaveFileDialog ([initialFolder,[initialFilename,[filters,[title]]]]) 

Set toolkit = CreateObject("VbsEdit.Toolkit")
filepath = toolkit.SaveFileDialog("c:\scripts","test.txt","Text Files (*.txt)|*.txt")

If Not(IsNull(filepath)) Then
  Set objFSO = CreateObject("Scripting.FileSystemObject")
  Set objFile = objFSO.CreateTextFile(filepath,True)
  objFile.WriteLine Date
  objFile.Close
Else
  Wscript.Quit
End If



SelectFolder method
Prompt the user to select a folder
toolkit.SelectFolder ([initialDir,[title]]) 

Set toolkit = CreateObject("VbsEdit.Toolkit")
myfolder=toolkit.SelectFolder("c:\scripts\","Please select a folder")

If Not(IsNull(myfolder)) Then
  WScript.Echo myfolder
Else
  Wscript.Quit
End If

…

…

(Actually, folder selection dialogs can be opened without VBSEdit toolkit, with BrowseForFolder method of Shell.Application object.)

（实际上，文件夹选择对话框可以在没有 VBSEdit 工具包的情况下打开，使用 Shell.Application 对象的 BrowseForFolder 方法。）